# `bfffo`

[M68K Documentation](https://asm-editor.specy.app/documentation/m68k.md) › [Instructions](https://asm-editor.specy.app/documentation/m68k/instruction.md)

Web page: https://asm-editor.specy.app/documentation/m68k/instruction/bfffo

**Find first one in bit field** · 68020 · 68000 with opt bit

Category: Logic

Finds the first 1 in a bit field and writes its bit offset to a data register.

Select `opt p=68020`, or use `opt bit` with the 68000 or 68010, before any code or data

## Flags

| Flag | Effect |
| --- | --- |
| X | not changed |
| N | depends on the result |
| Z | depends on the result |
| V | always 0 |
| C | always 0 |

## Forms

- `bfffo <ea>{offset:width}, Dn`
  - Source: Dn, (An), d(An), d(An,Xn), abs, d(PC), d(PC,Xn)

## Operands

- [`<ea>`](https://asm-editor.specy.app/documentation/m68k/addressing-mode.md): An operand using one of the addressing modes listed for this form. The list determines whether it can be a register, memory or an immediate value. With `opt p=68020`, an allowed `d(An,Xn)` or `d(PC,Xn)` mode also permits the corresponding 68020 indexed and memory indirect forms. See [68020 addressing](https://asm-editor.specy.app/documentation/m68k/addressing-mode/68020.md).
- [`{offset:width}`](https://asm-editor.specy.app/documentation/m68k/addressing-mode/bit-fields.md): A bit field: `width` bits that start `offset` bits below the operand’s most significant bit, written immediately after the operand. For example, `d0{24:8}` is the low byte of `d0`. A literal offset is 0 to 31 and a literal width is 1 to 32. Either may instead be a data register, as in `{d1:d2}`.
- [`Dn`](https://asm-editor.specy.app/documentation/m68k/addressing-mode/direct.md): A data register, `d0` to `d7`.

## Description

The search starts at the field’s highest bit. The result is the supplied field offset plus the number of leading zero bits in the field. If the field is all zeros, the result is offset + width, the position just after the field.

`bfffo d0{0:32}, d1` counts the leading zeros of `d0`. Subtract that count from 31 to obtain the highest set bit’s usual bit number. For a bitmap, the returned offset can identify the first slot marked by a 1.

N copies the field’s highest bit, and Z is set if no 1 was found. V and C are cleared, and X is unchanged.

Write the field as `{offset:width}` immediately after its operand. It selects 1 to 32 bits, counted from bit 31 of a data register or bit 7 of the byte at the memory address. The offset and width may each be a constant or a data register. See [bit fields](https://asm-editor.specy.app/documentation/m68k/addressing-mode/bit-fields.md) for their ranges, register values and wrapping rules.

## Example

```m68k
opt p=68020
* --- The highest bit set in a number ---
move.l #$12345, d0
bfffo d0{0:32}, d1 ; 15 zeros come before the first 1: d1 = 15
moveq #31, d2
sub.l d1, d2 ; d2 = 16: bit 16 is the highest bit set

* --- The first free slot of a bitmap, where 1 is free ---
lea slots, a0
bfffo (a0){0:16}, d3 ; slots 0 to 4 are taken: d3 = 5
bra END

slots:
    dc.w %0000010000000000

END:
```
